home *** CD-ROM | disk | FTP | other *** search
/ TPUG - Toronto PET Users Group / TPUG Users Group CD / TPUG Users Group CD.iso / C64 / B-Business / (c)b2.d64 / temp convert.c (.txt) < prev    next >
Commodore BASIC  |  2007-02-04  |  3KB  |  132 lines
  1. 100 REM***WEATHERMAN***
  2. 110 REM***WRITTEN BY GLENN PRESCOTT***
  3. 120 REM***REVISED BY ED MARCHESCHI***          **C64 CHANGES 3/1/83 BY WIM***
  4. 130 POKE53280,1:POKE53281,1:PRINT"[144][147]***WEATHERMAN***"
  5. 140 PRINT:PRINT
  6. 150 PRINT"SELECT THE PORTION OF THE PROGRAM YOU   WANT:"
  7. 160 PRINTTAB(4)"1. TEMPERATURE CONVERSION"
  8. 170 PRINTTAB(4)"2. TEMPERATURE HUMIDITY INDEX"
  9. 180 PRINTTAB(4)"3. WIND CHILL EQUIVALENT TEMPERATURE"
  10. 190 PRINTTAB(4)"[145]4. RELATIVE HUMIDITY AND DEW POINT"
  11. 200 PRINT:PRINT"ENTER YOUR SELECTION--"
  12. 210 INPUTS
  13. 220 PRINT:PRINT
  14. 230 ONSGOTO240,580,730,850
  15. 240 PRINT"[147]**TEMPERATURE CONVERSION**":PRINT
  16. 250 PRINT"INPUT TEMPERATURE AND SCALE SEPARATED   BY A COMMA."
  17. 260 PRINT"LET C=CELSIUS"
  18. 270 PRINT"    F=FAHRENHEIT"
  19. 280 PRINT"    K=KELVIN"
  20. 290 PRINT"    R=RANKINE"
  21. 300 PRINT"FOR EXAMPLE: 30,C OR 45,F"
  22. 310 PRINT:PRINT"ENTER TEMPATURE,SCALE--"
  23. 320 INPUTT,S$
  24. 330 IFS$<>"C"GOTO380
  25. 340 T1=T
  26. 350 T2=(9/5)*T+32
  27. 360 T3=T+273.15
  28. 370 T4=(9/5)*T3:GOTO510
  29. 380 IFS$<>"F"GOTO420
  30. 390 T2=T
  31. 400 T1=(5/9)*(T-32)
  32. 410 T=T1:GOTO360
  33. 420 IFS$<>"K"GOTO470
  34. 430 T3=T
  35. 440 T4=(9/5)*T
  36. 450 T2=T4-459.67
  37. 460 T1=(5/9)*(T2-32):GOTO510
  38. 470 IFS$<>"R"GOTO500
  39. 480 T3=(5/9)*T
  40. 490 T4=T:GOTO450
  41. 500 PRINT"INPUT ERROR, TRY AGAIN--":GOTO250
  42. 510 PRINT"    ";T1;"DEGREES CELSIUS"
  43. 520 PRINT"    ";T2;"DEGREES FAHRENHEIT"
  44. 530 PRINT"    ";T3;"DEGREES KELVIN"
  45. 540 PRINT"    ";T4;"DEGREES RANKINE":PRINT
  46. 550 PRINT"TRY AGAIN ? (Y OR N)":INPUTA$
  47. 560 IFA$="Y"GOTO310
  48. 570 IFA$="N"GOTO1380
  49. 580 PRINT"[147]    **TEMPERATURE HUMIDITY INDEX**":PRINT
  50. 590 PRINT"INPUT DRY BULB,WET BULB TEMPS IN        FAHRENHEIT DEGREES--"
  51. 600 PRINT"ENTER TEMP(DRY),TEMP(WET)"
  52. 610 INPUTD,W
  53. 620 C=0.4*(D+W)+15:PRINT
  54. 630 REM***T.H.I.=TEMPERATURE HUMIDITY INDEX***
  55. 640 PRINT"T.H.I.=";C
  56. 650 IFC>60GOTO670
  57. 660 PRINT"(BELOW COMFORT REGION)":GOTO700
  58. 670 IFC>70GOTO680:PRINT"(IN COMFORT REGION)":GOTO700
  59. 680 IFC>=80GOTO690:PRINT"(MARGINAL COMFORT REGION)":GOTO700
  60. 690 PRINT"(UNCOMFORTABLE REGION)":PRINT"(BEWARE OF HEAT EXHAUSTION)"
  61. 700 PRINT:PRINT"TRY AGAIN ? (Y OR N)":INPUTA$
  62. 710 IFA$="Y"GOTO600
  63. 720 IFA$="N"GOTO1380
  64. 730 PRINT"[147]     **WIND CHILL EQUIVALENT TEMP**"
  65. 740 PRINT
  66. 750 PRINT"INPUT TEMP IN FAHRENHEIT DEGREES, AND   WIND VELOCITY IN MPH"
  67. 760 INPUTD,U
  68. 770 U9=U/2.23694
  69. 780 D9=5/9*(D-32)
  70. 790 Q=33-(10.45+10*SQR(U9)-U9)*(33-D9)/22.034
  71. 800 Q=9/5*Q+32:PRINT
  72. 810 PRINT"EQUIVALENT WIND CHILL TEMP=";Q;"DEGREES":PRINT
  73. 820 PRINT"TRY AGAIN ? (Y OR N)":INPUTA$
  74. 830 IFA$="Y"GOTO750
  75. 840 IFA$="N"GOTO1380
  76. 850 PRINT"[147]     **RELATIVE HUMIDITY & DEW POINT**"
  77. 860 PRINT
  78. 870 PRINT"INPUT DRY BULB,WET BULB TEMPS IN        FAHRENHEIT DEGREES"
  79. 880 PRINT"ENTER TEMP(DRY),TEMP(WET)"
  80. 890 INPUTD1,W1:PRINT
  81. 900 PRINT"USE STANDARD A TM PRESSURE ? (Y OR N)"
  82. 910 INPUTA$
  83. 920 IFA$="Y"GOTO970
  84. 930 PRINT"ENTER A TM PRESSURE,SCALE (M=MILLIBARS, I=INCHES OF MERCURY)"
  85. 940 INPUTA,H$
  86. 950 IFH$="M"GOTO980
  87. 960 A=A/0.750062:GOTO980
  88. 970 A=1013.26
  89. 980 S=373.16
  90. 990 I=273.16
  91. 1000 T=D1
  92. 1010 GOSUB1240
  93. 1020 D2=T2:E1=E:T=W1
  94. 1030 GOSUB1240
  95. 1040 W2=T2:E2=E
  96. 1050 E3=A*(D2-W2)*(.00066*(1+.00115*W2))
  97. 1060 H=100*(E2-E3)/E1:P=E2-E3:T=D1
  98. 1070 GOSUB1240
  99. 1080 IFE=PGOTO1120
  100. 1090 T=T-0.1
  101. 1100 GOSUB1240
  102. 1110 IFE>PGOTO1090
  103. 1120 N9=INT(T):N5=T-N9
  104. 1130 IFN5>=0.5GOTO1150
  105. 1140 T=N9:GOTO1160
  106. 1150 T=INT(T+0.5)
  107. 1160 PRINT:PRINT
  108. 1170 PRINT"     TEMP(DRY)=";D1
  109. 1180 PRINT"     TEMP(WET)=";W1
  110. 1190 PRINT"TEMP DEW POINT=";T
  111. 1200 PRINT"  REL HUMIDITY=";H:PRINT
  112. 1210 PRINT"TRY AGAIN ? (Y OR N)":INPUTA$
  113. 1220 IFA$="Y"GOTO860
  114. 1230 IFA$="N"GOTO1380
  115. 1240 T2=5/9*(T-32):T3=T2+273.15
  116. 1250 IFT<=32GOTO1320
  117. 1260 V=-7.90298*(S/T3-1)
  118. 1270 W=5.02808*LOG(S/T3)
  119. 1280 X=-.00000013816*(10^(11.344*(1-T3/S))-1)
  120. 1290 Y=.0081328*(10^(-3.49149*(S/T3-1))-1)
  121. 1300 E9=V+W+X+Y+3.0057209
  122. 1310 E=10^(E9):RETURN
  123. 1320 V=-9.09718*(I/T3-1)
  124. 1330 W=-3.56654*LOG(I/T3)
  125. 1340 X=.876793*(1-T3/I)
  126. 1350 E9=V+W+X+.785835
  127. 1360 E=10^(E9)
  128. 1370 RETURN
  129. 1380 PRINT"NEW SELECTION ? (Y OR N)":INPUTA$
  130. 1390 IFA$="Y"GOTO130
  131. 1400 END
  132.